以上这些肯定有用。我想过这样写逻辑。但这里的代码很长。

A = LOAD 'input.txt' AS (from,to,duration);
B = GROUP A BY (from,to);
C = FOREACH B GENERATE FLATTEN(group) AS(from,to),COUNT(A.from) as count;
D = ORDER C BY count DESC;
E = LIMIT D 1;
F = JOIN C by count,E BY $2;
G = FOREACH F GENERATE $0,$1,$2;

如果你觉得有用，请检查一下

你能试着告诉我这对你有用吗。
更新：
如果你没有 RANK 操作员，下载 piggbank.jar 并将其设置在类路径中，然后尝试下面的方法。
输入文件

5       10      1
10      30      15
10      30      25
5       10      10
10      40      15
5       20      5

pigscript:pig version<11

REGISTER /tmp/piggybank.jar;

    DEFINE MyOver org.apache.pig.piggybank.evaluation.Over('myrank:int');
    DEFINE MyStitch org.apache.pig.piggybank.evaluation.Stitch;

    A = LOAD 'input.txt' AS (from,to,duration);
    B = GROUP A BY (from,to);
    C = FOREACH B{
                    mycount = COUNT($1);
                    GENERATE group, mycount AS cnt;
                 }
    D = GROUP C ALL;
    E = FOREACH D  {
                      mysort = ORDER C BY cnt DESC;
                      GENERATE FLATTEN(MyStitch(mysort,MyOver(mysort,'dense_rank',0,1,1)));
                   };
    F = FILTER E BY stitched::myrank==1;
    G = FOREACH F GENERATE FLATTEN(stitched::group),stitched::cnt;
    DUMP G;

输出：

(5,10,2)
(10,30,2)

pigscript:pigversion >=11支持秩运算符

A = LOAD 'input.txt' AS (from,to,duration);
B = GROUP A BY (from,to);
C = FOREACH B{
                mycount = COUNT($1);
                GENERATE group, mycount AS cnt;
             }
D = RANK C BY cnt DESC;
E = FILTER D BY rank_C==1;
F = FOREACH E GENERATE FLATTEN(group),cnt;
DUMP F;

输出：

(5,10,2)
(10,30,2)