下面是一个快速脚本，它可以实现您正在寻找的功能：

import java.text.*
import groovy.xml.*

def text = '''
<root>
  <results>
    <loc>Loc 10</loc>
    <loc_name>Loc Desc10</loc_name>
    <points>3</points>
    <StartDate>2023-09-11T22:39:40Z</StartDate>
    <EndDate>2023-09-13T22:45:36.437000Z</EndDate>
  </results>
  <results>
    <loc>Loc 11</loc>
    <loc_name>Loc Desc 11</loc_name>
    <points>4</points>
    <StartDate>2023-09-16T22:39:40Z</StartDate>
    <EndDate>2023-09-18T22:45:36.437000Z</EndDate>
  </results>
</root>
'''

def xml = new XmlSlurper().parseText( text )
SimpleDateFormat parser = new SimpleDateFormat("yyyy-MM-dd'T'HH:mm:ssX")
SimpleDateFormat endParser = new SimpleDateFormat("yyyy-MM-dd'T'HH:mm:ss.SSSX")
def output = new XmlParser().parseText("<root/>")

xml.results.each { resXml ->
   Date startDate = parser.parse( resXml.StartDate.text() )
   Date endDate = endParser.parse( resXml.EndDate.text() )
   
   Date currentDate = new Date( startDate.time )
   while( currentDate < endDate ) {
       Node resultsNode = output.appendNode( new QName("results"), [:] )
       resXml.children().findAll { child -> child.name() != "StartDate" && child.name() != "EndDate" }.each { child ->
          resultsNode.appendNode( new QName(child.name()), [:], child.text() )
       }
       resultsNode.appendNode(new QName("Date"), [:], parser.format( currentDate ))
       currentDate = currentDate + 1
   }
}
println( XmlUtil.serialize(output ) )

我注意到了一些事情，应该解释一下。StartDate节点和EndDate节点具有不同的日期格式。感觉很奇怪。如果您控制这个XML的生成，您可能需要清理它。
诀窍在于parseText返回一个GPathResult，它允许你跨xml节点执行查询（比如xml.results.each跨根元素下的节点执行查询）。你还可以访问groovy的集合方法（如findAll，collect，each等）。因此，用于将节点从输入文档复制到输出的循环使用findAll来过滤所有不是StartDate或EndDate的节点，使用each进行迭代。