不能有两个模块具有相同的（包）名称。
您有两个遵循此模式的文件：

package Kernel::Module1;

...

sub some_sub_or_method { ... }

...

这基本上相当于

package Kernel::Module1;

...

BEGIN { *some_sub_or_method = sub { ... }; }

...

因此，加载/执行这两个文件将导致

package Kernel::Module1;

...

BEGIN { *some_sub_or_method = sub { ... }; }

...

package Kernel::Module1;

...

BEGIN { *some_sub_or_method = sub { ... }; }

...

第二次赋值将撤消第一次赋值。你不能有两个具有相同（包）名称的模块。
如果你想让Kernel：：Module 1的用户得到一个修改过的版本，你需要求助于monkey patching。

package My::Patch::Kernel::Module1;

use strict;
use warnings;

use Kernel::Module1 qw( );
use Sub::Name       qw( subname );
 
{
   my $old = \&Kernel::Module1::some_sub_or_method;

   my $new = subname some_sub_or_method => sub {
      ...

      $old->();   # Optionally call original sub/method.

      ...
   };

   no warnings qw( redefine );
   *Kernel::Module1::some_sub_or_method = $new;
}

1

@ikegami的回答让我使用Class：：Monkey lib来解决这个问题，它允许我调用原始方法而不会出错：
.\main.pl：

#!/usr/bin/perl
use strict;
use warnings;

use lib '.';
use lib './Custom';

use Kernel::Module1Patch;

my $module1 = Kernel::Module1Patch->new();

print $module1->subRoutine();

.\Kernel\Module1：

#!/usr/bin/perl
package Kernel::Module1;

use strict;
use warnings;

sub new {
    my $class = shift;
    return bless {}, $class;
}

sub subRoutine {
  return "original";
}
1;

.\Custom\Kernel\Module1Patch：

package Kernel::Module1Patch;

use Class::Monkey qw<Kernel::Module1>;
 
# The patch
around 'subRoutine' => sub {
    my $originalSubRoutine = shift;
    my $self = shift;
    return 'around' . $self->$originalSubRoutine(@_);
},
qw<Kernel::Module1>;
# /The Patch

1;

返回结果：

aroundoriginal