You're going to have to perform a dynamic pivot on your data first; pivoting on all the distinct values in your key column, and projecting them as distinct columns. And then doing your for json path, without_array_wrapper .

Here's an example of how that could work.

drop table if exists #data
create table #data
(
    K varchar(30),
    V varchar(30)
)

insert into #data
select 'key1', 'value1' union all
select 'key2', 'value2' union all
select 'key3', 'value3' 

declare 
    @Columns nvarchar(max),
    @SQL nvarchar(max),
    @JSON nvarchar(max)

select @Columns = string_agg(quotename(K), ',')
from #data

select @SQL = 
concat
('
    select @JSON = 
    (
        select ' , @Columns, '
        from #data d
        pivot (max(V) for K in (', @Columns, ')) p
        for json path, without_array_wrapper
    )
')

exec sp_executesql 
    @sql,
    N'@JSON nvarchar(max) output',
    @Json output

select @JSON

This outputs

{"key1":"value1","key2":"value2","key3":"value3"}

Here's another SO article on dynamic pivots . The concept is the same, you're just wrapping the results in a for json call.