我将draw_ball proc的最后一部分修改为以下代码：

mov ax,dx
    mov bx,BALL_Y   
    add bx,10
    cmp dx,bx        
    jng DRAW_BALL_HORIZONTAL

字符串
因为ball_y是代码开始画球的第一行，画球应该在ball_y + 10结束。

在VGA mode 13h中对每个像素使用中断会使它慢得无法接受;最好直接写入位于段地址A000 h的视频存储器。此外，程序格式COM更适合初学者，因为您不必为堆栈和段寄存器初始化而烦恼。
我试着用€ASM写你的作业，用euroasm.exe Ayxux.asm组装它，它像预期的那样工作。

Ayxux PROGRAM Format=COM
        MOV AH, 00h     ; Set the video mode configuration
        MOV AL, 13h     ; Choose the video mode (320x200 256-color VGA mode).
        INT 10h         ; Execute the configuration
        MOV AX,0A000h
        MOV ES,AX        ; Let ES address videomemory
        CALL DRAW_BALL
        MOV AH,0
        INT 16h           ; Wait for keypress.
        MOV AX,0003h
        INT 10h           ; Restore text video mode 80*25 before termination.
        RET               ; Return to DOS.

DRAW_BALL PROC            ; Calculate address of the ball: DI=320*BALL_Y + BALL_X
       MOV AX,320         ; Size of one videoline.
       MUL [BALL_Y]
       ADD AX,[BALL_X]
       MOV DI,AX
       MOV AL,[BALL_COLOR]
       MOV BX,[BALL_SIZE]
       MOV DX,BX          ; Initialize row counter DX.
  DRAW_BALL_HORIZONTAL:
       MOV CX,BX          ; Initialize column counter CX.
       REP STOSB          ; Store CX pixels with color AL to videomemory at ES:DI, increment DI.
       SUB DI,BX          ; Return the pointer back to initial column.
       ADD DI,320         ; Point at the next row.
       DEC DX
       JNZ DRAW_BALL_HORIZONTAL ; The next ball row.
       RET
     ENDP DRAW_BALL

BALL_X     DW 0Ah          ;current X position (column) of the ball
BALL_Y     DW 0Ah          ;current Y position (line) of the ball
BALL_SIZE  DW 04h          ;size of the ball (how many pixels does the ball have in width and height)
BALL_COLOR DB 0Fh          ; Pixel color 0..255.
    ENDPROGRAM Ayxux

字符串

第1期

STACK SEGMENT PARA STACK
    DB 64 DUP (' ')
STACK ENDS

字符串
64字节对于一个堆栈来说太少了，如果你使用的是BIOS功能的话，我建议是512字节。

第2期

PUSH DS         ; Push the DS segment to the stack
SUB AX, AX      ; Clean the AX register
PUSH AX         ; Push AX to the stack
...
POP AX          ; Release top item from stack
POP AX          ; Release top item from stack

型
您需要删除这些pop。这两个被压入堆栈的项对于您的.EXE程序能够使用单个ret（far）指令退出到DOS是必不可少的。

第三期

INC CX
MOV AX,CX
SUB AX,BALL_X
CMP AX,BALL_SIZE
JNG DRAW_BALL_HORIZONTAL

型
著名的一次性错误！这将产生5像素，而BALL_SIZE等于4。简单地写：

JB  DRAW_BALL_HORIZONTAL

型

第四期

MOV CX,BALL_X ;the CX register goes back to initial column
INC DX ;DX = DX + 1
MOV AX,DX
SUB DX,BALL_Y         <<< typo
CMP AX,BALL_SIZE
JNG DRAW_BALL_HORIZONTAL

型
同样的一次性错误，但这次由于打字错误而加重！sub需要从临时寄存器AX中减去。

MOV AX,DX
SUB AX,BALL_Y
CMP AX,BALL_SIZE
JB  DRAW_BALL_HORIZONTAL

型

第五期

MOV AH, 0Bh     ; Set the background color
MOV BH, 00h     ; Page number (usually 0)
MOV BL, 00h     ; Choose black as the background color
INT 10h         ; Execute the configuration

型
这是多余的代码。在设置了320 x200 256色图形模式13 h后，背景已经默认为黑色。